This is a technical post meant for ActionScript developers.

Flash CS3 and ActionScript 3 projects have no means (by default) of using flash remoting. Since we, at Rhinofly, do projects in Flex, Flash CS3 and pure ActionScript 3 we needed remoting to function in all of the project types. I was given the task to find out how we could use AMF 3 remoting within Flash CS3 and ActionScript 3 projects.

Note that this has only been tested with ColdFusion 7.02 as backend.
Doing a call

Three imporant classes needed for communication are:

mx.messaging.messages.RemotingMessage
mx.messaging.messages.AcknowledgeMessag
mx.messaging.messages.ErrorMessage

These can be found in the ${FRAMEWORKS}\libs\rpc.swc package, so make sure you add this package to your project.

To make a call you can use the following code:

//register the correct class aliases
registerClassAlias("flex.messaging.messages.RemotingMessage", RemotingMessage);
registerClassAlias("flex.messaging.messages.AcknowledgeMessage", AcknowledgeMessage);
registerClassAlias("flex.messaging.messages.ErrorMessage", ErrorMessage);

//create a netconnectionvar nc:NetConnection = new NetConnection();
nc.connect("http://www.domain.com/flex2gateway/");

//create the arguments that will be sent to the method
var methodArguments:Array = new Array();

//create a remoting message
var remotingMessage:RemotingMessage = new RemotingMessage();
remotingMessage.operation = "methodToCall";
remotingMessage.source = "CFCToCall";
remotingMessage.body = methodArguments;

//The values of these 2 values come from the services-config.xml which is located in the ColfFusion server
remotingMessage.destination = "ColdFusion";
remotingMessage.headers = {DSEndpoint: "my-cfamf"};

//create a responder
var responder:Responder = new Responder(result, fault);

//make the call
nc.call(null, responder, remotingMessage);

You will most likely get the following error:

ArgumentError: Error #2004: One of the parameters is invalid.

This problem can be solved in 2 ways:

1. Turn of debugging on the ColdFusion server
2. Read on

Within the debugging information sent back to the flash client there is an object typed as ArrayCollection. In order to use the ArrayCollection in our project we need to add ${FRAMEWORKS}/libs/flex.swc to our project. Use the following code to register the class:

registerClassAlias("flex.messaging.io.ArrayCollection", ArrayCollection);

The ArrayCollection is depends on a resource bundle so we need to add ${FRAMEWORKS}\locale\{locale} aswell.

Handling the response

The response methods should look like this.

function result(result:AcknowledgeMessage):void
{
   //result.body contains the actual data
};

function fault(result:ErrorMessage):void
{
};

I hope this helps any developers out there.